☰

Как создать несколько файлов одного файла в нескольких каталогах?

tag-icon • tag-icon windows command-line-interface windows-command-prompt ms-dos
Как создать несколько файлов одного файла в нескольких каталогах?

Здравствуйте, я пытаюсь создать несколько копий одного файла в нескольких каталогах.

например, у меня есть 6 папок с одним файлом в каждой папке с именем lp.html. Как мне запустить пакет для создания 100 копий указанных файлов в каждом каталоге?

Мой код создает несколько копий, но мне приходится делать это по одной, и это становится утомительным, когда мне нужно обработать более 100 папок.

Так как же мне заставить этот пакетный файл сделать то, что я пытаюсь сделать. [Я работаю под управлением Windows 7]

ДОБАВЛЕННАЯ ИНФОРМАЦИЯ: Все папки находятся в одной родительской папке, файлы в папках отличаются друг от друга

   @echo off

   for /L %%i IN (1,1,100) do call :docopy %%i
   goto end

   :docopy
   set FN=00%1
   set FN=%FN:~-3%

   copy source-file.html poll%FN%.html

   :end

решение1

Используйте команду forfiles. Запустите forfiles /? для получения справки.

Если вас беспокоит параллельная обработка копий, вы можете создать 6 разных скриптов, по одному для каждого каталога, а затем запустить их все из одного скрипта, start scriptname.batкоторый не будет ждать возвращаемого значения, как callэто делает .

решение2

Попробуйте это. Это некрасиво, потому что этот *$#? редактор потерял отступы, переносы строк и т. д.

--- ПЕРЕСМОТРЕННЫЙ СЦЕНАРИЙ

@echo off

setlocal

set ROOT_DIR=c:\temp\test

for /f "tokens=*" %%D in ('dir /ad /b "%ROOT_DIR%"') do call :PROCESS_DIR "%ROOT_DIR%" "%%D"

endlocal

goto END


:PROCESS_DIR

set PD_ROOT=%1
set PD_ROOT=%PD_ROOT:"=%
set PD_DIR=%2
set PD_DIR=%PD_DIR:"=%
set PD_FIRST_FILE=
set PD_SOURCE_FILE=

REM ***
REM *** GET THE NAME OF THE FIRST FILE IN THIS FOLDER.
REM ***
for /f "tokens=*" %%F in ('dir /o-n /b "%PD_ROOT%\%PD_DIR%"') do set PD_FIRST_FILE=%%F

if "%PD_FIRST_FILE%" == "" (
    echo WARNING : No files found in [%PD_DIR%] - skipping.
    goto END
    )

set PD_SOURCE_FILE=%PD_ROOT%\%PD_DIR%\%PD_FIRST_FILE%

REM ***
REM *** CREATE FILES.
REM ***
for /l %%I in (1,1,100) do call :CREATE_FILE_COPY "%PD_ROOT%\%PD_DIR%" "%PD_SOURCE_FILE%" 00%%I

goto END

:CREATE_FILE_COPY

set CFP_DIR=%1
set CFP_DIR=%CFP_DIR:"=%
set CFP_FILE=%2
set CFP_INDEX=%3
set CFP_FILE_NO_EXT=

REM ***
REM *** GET FILE NAME WITHOUT EXTENSION.
REM ***
for /f %%F in ("%CFP_FILE%") do set CFP_FILE_NO_EXT=%%~nF

REM ***
REM *** COPY THE FILE.
REM ***
copy /y %CFP_FILE% "%CFP_DIR%\%CFP_FILE_NO_EXT%.%CFP_INDEX:~-3%

goto END


:END

Связанный контент